examples/QtQuick/qmlaudioplayer/qml/qmlaudioplayer/AudioPlayerPage.qml

import QtQuick 1.0
import QtMultimediaKit 1.1
import com.nokia.symbian 1.0

Page{
    tools: commonTools

    property alias myaudio: audio

    ToolBarLayout {
        id: commonTools
        ToolButton {
            flat: true
            iconSource: "toolbar_back.svg"
            onClicked: Qt.quit()
        }
        ToolButton {
            flat: true
            iconSource: "toolbar_options.svg"
            onClicked: pageStack.push(filePickerPage)
        }
    }



    Audio{ id: audio; source: "music.wav"; volume: 0.5 }

    Row{
        id: audioControls
        width: parent.width
        anchors.bottom: parent.bottom
        height: 80
        Button{
            width: parent.width/2
            iconSource: "toolbar_play.svg"
            onClicked: audio.play()
        }
        Button{
            width: parent.width/2
            iconSource: "toolbar_stop.svg"
            onClicked: audio.stop()
        }
    }

    Item {
        id: seekSlider

        anchors { bottom: audioControls.top; bottomMargin: 25 }
        width: parent.width
        height: slider.height + positionTime.height

        Slider {
            id: slider

            anchors.top: parent.top
            width: parent.width
            maximumValue: audio.duration
            stepSize: 1000

            onPressedChanged: {
                if (!pressed)
                    audio.position = value
            }

            Binding {
                target: slider
                property: "value"
                value: audio.position
                when: !slider.pressed
            }
        }

        Text {
            id: positionTime

            anchors { left: parent.left; top: slider.bottom; leftMargin: 15; topMargin: 4 }
            color: "white"
            font.pixelSize: 18
            text: audio.position/1000
        }

        Text {
            id: durationTime

            anchors { right: parent.right; top: slider.bottom; rightMargin: 15; topMargin: 4 }
            color: "white"
            font.pixelSize: 18
            text: audio.duration/1000 - audio.position/1000
        }
    }

    Item {
        id: infoText

        anchors { bottom: seekSlider.top; bottomMargin: 36 }
        width: parent.width
        height: title.height + artist.height + 15
        clip: true

        Text {
            id: artist

            width: parent.width
            anchors { bottom: title.top; bottomMargin: 18 }
            horizontalAlignment: Text.AlignHCenter
            //audio.metaData.albumArtist
            text: audio.metaData.albumArtist
            color: "white"
            font.pixelSize: 28
            wrapMode: Text.WordWrap
            visible: audio.metaData.albumArtist != "" ? true : false

            Behavior on text {
                NumberAnimation {
                    target: artist
                    property: "opacity"
                    from: 0
                    to: 1
                    duration: 1000
                }
            }
        }

        Text {
            id: title

            width: parent.width
            anchors.bottom: parent.bottom
            horizontalAlignment: Text.AlignHCenter
            //audio.metaData.title
            text: audio.metaData.title
            color: "white"
            font.pixelSize: 20
            wrapMode: Text.WordWrap

            Behavior on text {
                NumberAnimation {
                    target: title
                    property: "opacity"
                    from: 0
                    to: 1
                    duration: 1000
                }
            }
        }

    }

}

---