examples/QtQuick/qmlnotifyfriends/qml/qmlnotifyfriends/ContactsPage.qml

/****************************************************************************
**
** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Nokia Corporation
**
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
**     the names of its contributors may be used to endorse or promote
**     products derived from this software without specific prior written
**     permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 1.0
import com.nokia.symbian 1.0
import QtMobility.contacts 1.1


Page {
    tools: contactsTools

    property alias myContacts: myContactModel
    property string selectedContact: ""
    property int selectedContactId: 0

    Component {
        id: heading

        PageHeading {
            id: headingText
            width: parent.width
            text: qsTr("Notify friends")
        }
    }

    // ContactModel element, intialise it with 'symbiansim' manager.
    ContactModel{
        id: myContactModel
        manager: "symbiansim"
        autoUpdate: true
    }

    // List view of contacts.
    ListView{
        id: myContactList
        header: heading
        anchors.fill: parent
        model: myContactModel
        delegate:
            Rectangle{
            width: parent.width
            height: 75
            color: "black"
            border.color: "grey"
            //opacity: 0
            Column{
                anchors.top: parent.top
                anchors.topMargin: 5
                anchors.left: parent.left
                anchors.leftMargin: 5
                width: parent.width
                height: parent.height
                Text{
                    color: "white"
                    text: {(contact.name.firstName + contact.name.lastName == "")
                          ? contact.displayLabel : contact.name.firstName +
                            contact.name.lastName }

                    font.pointSize: 9
                    font.bold: true
                }

                Text{
                    color: "white"
                    text: contact.phoneNumber.number
                    font.pointSize: 7
                }

            }
            MouseArea{
                anchors.fill: parent
                onPressAndHold: {
                    parent.color = "grey"
                    contextMenu.open()
                    selectedContact = contact.phoneNumber.number
                    selectedContactId = index
                }

                onPositionChanged: parent.color = "black"
                onReleased: parent.color = "black"
            }
        }


        spacing: 5
        clip: true
        highlightMoveDuration: 500


        ScrollDecorator {
            flickableItem: parent
        }

    }


    ToolBarLayout {
        id: contactsTools
        ToolButton {
            flat: true
            iconSource: "toolbar_back.svg"
            onClicked: Qt.quit()
        }
        ToolButton {
            flat: true
            iconSource: "toolbar_options.svg"
            onClicked:{
                viewMenu.open();
            }
        }
    }


    /*
      Menu used to add contacts, change the settings from SIM memory to phone and vice-versa
    */
    Menu{
        id: viewMenu

        content:
            Column{
            width: viewMenu.width

            MenuItem{
                text: qsTr("Add Contact")
                onClicked:{
                    pageStack.push(addContactPage);
                    viewMenu.close();
                }
            }

            MenuItem{
                text: qsTr("Settings")
                onClicked:{
                    settingsDialog.open();
                    //pageStack.push(settingsPage);
                    viewMenu.close();
                }
            }
        }
    }

    // ContextMenu is used to add and delete contacts.
    ContextMenu{
        id: contextMenu

        content:
            Column{
            width: contextMenu.width

            MenuItem{
                text: qsTr("Add Contact")
                onClicked:{
                    pageStack.push(addContactPage);
                    contextMenu.close();
                }
            }

            MenuItem{
                text: qsTr("Delete Contact")
                onClicked:{
                    myContactModel.removeContact(myContactModel.contacts[selectedContactId].contactId)
                    contextMenu.close();
                }
            }

            MenuItem{
                text: qsTr("Add Notification Alarm")
                onClicked:{
                    pageStack.push(addAlarmPage);
                    contextMenu.close();
                }
            }
        }
    }

    // Settings dialog is used to change the contacts manager.
    SettingsDialog{ id: settingsDialog; width: 360; height: 250 }

    // Connections for signals emitted by SettingsDialog.
    Connections{
        target: settingsDialog
        onAccepted:{
            if(settingsDialog.phoneMemory == true)
                myContacts.manager = "symbian"
            else if(settingsDialog.simMemory == true)
                myContacts.manager = "symbiansim"
        }
    }
}

---