examples/QtQuick/qmlaudioplayer/qml/qmlaudioplayer/mainwindow.qml

/****************************************************************************
**
** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Nokia Corporation
**
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
**     the names of its contributors may be used to endorse or promote
**     products derived from this software without specific prior written
**     permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 1.0
import com.nokia.symbian 1.0
import SampleFileBrowser 1.0

ApplicationWindow{
    id:main

    // Audio player component.
    Player{ id: player }

    ToolBarLayout {
        id: commonTools
        ToolButton {
            flat: true
            iconSource: "toolbar_back.svg"
            onClicked: Qt.quit()
        }
        ToolButton {
            flat: true
            iconSource: "toolbar_options.svg"
            onClicked: browseFile.openDialog()
        }
    }


    Page{
        id: simpleAudioPlayerPage
        tools: commonTools


        MyFileBrowser{ id: browseFile }

        PageHeading{
            id: heading
            anchors.top: parent.top
            width: parent.width
            text: qsTr("Simple Audio player")
        }

        Row{
            id: audioControls
            width: parent.width
            height: 80
            anchors.bottom: parent.bottom

            Button{
                width: parent.width/2
                iconSource: player.playing ? "toolbar_pause.svg" : "toolbar_play.svg"
                onClicked: player.playing ? player.pause() : player.play()
            }

            Button{
                width: parent.width/2
                iconSource: "toolbar_stop.svg"
                onClicked: player.stop()
            }
        }

        Item {
            id: seekSlider

            anchors { bottom: audioControls.top; bottomMargin: 25 }
            width: parent.width
            height: slider.height + positionTime.height

            Slider {
                id: slider

                anchors.top: parent.top
                width: parent.width
                maximumValue: player.duration
                stepSize: 1000

                onPressedChanged: {
                    if (!pressed)
                        player.position = value
                }

                Binding {
                    target: slider
                    property: "value"
                    value: player.position
                    when: !slider.pressed
                }
            }

            Text {
                id: positionTime

                anchors { left: parent.left; top: slider.bottom; leftMargin: 15; topMargin: 4 }
                color: "white"
                font.pixelSize: 18
                text: player.positionTime
            }

            Text {
                id: durationTime

                anchors { right: parent.right; top: slider.bottom; rightMargin: 15; topMargin: 4 }
                color: "white"
                font.pixelSize: 18
                text: player.durationTime
            }
        }

        Item {
            id: infoText

            anchors { bottom: seekSlider.top; bottomMargin: 36 }
            width: parent.width
            height: title.height + artist.height + 15
            clip: true

            Text {
                id: artist

                width: parent.width
                anchors { bottom: title.top; bottomMargin: 18 }
                horizontalAlignment: Text.AlignHCenter
                //audio.metaData.albumArtist
                text: player.artist
                color: "white"
                font.pixelSize: 28
                wrapMode: Text.WordWrap
                visible: player.artist != "" ? true : false

                Behavior on text {
                    NumberAnimation {
                        target: artist
                        property: "opacity"
                        from: 0
                        to: 1
                        duration: 1000
                    }
                }
            }

            Text {
                id: title

                width: parent.width
                anchors.bottom: parent.bottom
                horizontalAlignment: Text.AlignHCenter
                text: player.title
                color: "white"
                font.pixelSize: 20
                wrapMode: Text.WordWrap

                Behavior on text {
                    NumberAnimation {
                        target: title
                        property: "opacity"
                        from: 0
                        to: 1
                        duration: 1000
                    }
                }
            }

        }

        Connections{
            target: browseFile
            onFileSelected: player.source = newSourceFile
        }

    }


    Component.onCompleted: pageStack.push(simpleAudioPlayerPage)
}

---