examples/QtQuick/qmlnetworkinfo/qml/qmlnetworkinfo/main.qml

/****************************************************************************
**
** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Nokia Corporation
**
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
**     the names of its contributors may be used to endorse or promote
**     products derived from this software without specific prior written
**     permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 1.0
import com.nokia.symbian 1.0
import QtMobility.systeminfo 1.1

ApplicationWindow {
    id: window

    function setStateIfFound(target, name) {
        for (var i = 0; i < target.states.length; i++) {
            var curState = target.states[i];
            if(curState.name == name) {
                target.state = name
                break
            }
        }
    }

    ToolBarLayout {
        id: commonTools
        ToolButton {
            flat: true
            iconSource: "toolbar_back.svg"
            onClicked: pageStack.depth <= 1 ? Qt.quit() : pageStack.pop()
        }
        ToolButton {
            flat: true
            iconSource: "toolbar_options.svg"
        }
    }

    Page {
        id: page
        //anchors.fill: parent
        tools: commonTools

        Component.onCompleted: {
            if(screen.currentOrientation == Screen.Portrait) {
                setStateIfFound(page, "PortraitState")
            } else if(screen.currentOrientation == Screen.Landscape) {
                setStateIfFound(page, "LandscapeState")
            }
        }

        PageHeading{
            id: heading
            anchors.top: parent.top
            width: parent.width
            text: qsTr("Network Information")
        }

        // Network Info element.
        NetworkInfo{
            id:myNetworkInfo
        }

        // Displays the details of the network information.
        TextArea{
            id: displayInfo
            anchors.top: heading.bottom
            anchors.topMargin: 10
            font.pointSize: 8
            anchors.left: parent.left
            anchors.leftMargin: 10
            width: parent.width
            readOnly: true
            text: {
                "Current MCC : " + myNetworkInfo.currentMobileCountryCode + "\n" +
                 "Cell ID : " + myNetworkInfo.cellId + "\n" +
                 "Current MNC : " + myNetworkInfo.currentMobileNetworkCode + "\n" +
                 "Current Mode : " + myNetworkInfo.currentMode + "\n" +
                 "Network name : " + myNetworkInfo.networkName + "\n" +
                 "Home MCC : " + myNetworkInfo.homeMobileCountryCode + "\n" +
                 "Home MNC : " + myNetworkInfo.homeMobileNetworkCode + "\n" +
                 "Location Area Code : " + myNetworkInfo.locationAreaCode + "\n" +
                 "Network Status : " + myNetworkInfo.networkStatus + "\n" +
                 "Network Signal Strength : " + myNetworkInfo.networkSignalStrength
            }
        }

        Text{
            id: smsStatus
            width: parent.width
            anchors.top: displayInfo.bottom
            anchors.topMargin: 10
            anchors.leftMargin: 10
            text: "Sms delivery status..."
            color: "white"
        }

        // Settings window, which is used to enter the sender list numbers.
        SettingsPage{ id: settingsPage }

        // List of options, to send an Sms, setting the senders list of numbers.
        Column{
            id: optionsList
            anchors.bottom: parent.bottom
            anchors.bottomMargin: 20
            spacing: 10
            anchors.left: parent.left
            anchors.leftMargin: 20
            anchors.rightMargin: 20
            anchors.right: parent.right

            Button{
                id: sendSmS
                width: parent.width
                text: "Send SMS"
                onClicked:{
                    smsStatus.text = "Calling send message";
                    mymessaging.sendMessage( displayInfo.text, settingsPage.num1, settingsPage.num2
                                            , settingsPage.num3);
                }
            }

            Button{
                id: settings
                width: parent.width
                text: "Settings"
                onClicked:{
                    pageStack.push(settingsPage);
                }
            }
        }

        // Display the state change message for the message sent, when signal is emitted.
        Connections{
            target: mymessaging
            onMsgStatusReceived:{
                smsStatus.text = response;
            }
        }

        Connections {
            target: screen
            onCurrentOrientationChanged: {
              if(screen.currentOrientation == Screen.Portrait) {
                page.state = 'PortraitState'
              }
              if(screen.currentOrientation == Screen.Landscape) {
                page.state = 'LandscapeState'
              }
            }
        }

        states: [
            State {
                name: "PortraitState"

                AnchorChanges {
                    target: optionsList
                    anchors.left: parent.left
                }

                AnchorChanges {
                    target: smsStatus
                    anchors.top: displayInfo.bottom
                    anchors.left: parent.left
                }
            },
            State {
                name: "LandscapeState"

                AnchorChanges {
                    target: optionsList
                    anchors.left: displayInfo.right
                }

                AnchorChanges {
                    target: smsStatus
                    anchors.top: heading.bottom
                    anchors.left: displayInfo.right
                }

                PropertyChanges {
                    target: displayInfo
                    width: parent.width/2
                }
            }
        ]
    }
    Component.onCompleted: pageStack.push(page)
}

---